edu mk1用アニメ表示ソフト

EDU mk1用のアニメーション表示ソフトを作ってみました。
データをSDカードから直接読み込みながら表示しますので、長時間のアニメ再生が可能です。
http://nicotak.com/nicobasic/edu/edu1ani.zip

▲32x16ピクセルのBMPファイルを用意します。
形式は16色でも24bitカラーでも問題ありません。
黒色＝点灯なし、それ以外の色＝点灯ありと判断します。

▲BMPファイルを0001.bmpから連番にします。
アニメ枚数の上限は999枚までです。

▲専用のプログラムを使って拡張子がaniというファイルに結合します。
aniファイルは画面のモノクロ2値データ(32x16/8=64バイト)が連続した、単なるベタデータです。

結合するプログラムはこれです。

//---------------------------------------------------------
// BMPファイル結合
// 32x16pixelモノクロのBMPファイルを1個のaniファイルに結合します。
// by takuya matsubara
// このプログラムはフリーソフトです。
//---------------------------------------------------------
//#include "hspext.as"

sdim fname,48
sdim fbuf,100000
	pos 150,10
	print "****.bmpを読み込んでaniファイルに結合"
	pos 150,35
	print "BMPファイル枚数(1-)"
	fmax = 999
	pos 300,50
	input fmax,100,25

	pos 300,100
	objsize 200,30
	button gosub "aniファイル作成",*conv
	stop
	end
*conv
	if(fmax > 999){
		dialog "999までにしてください"
		return
	}
	if(fmax < 1){
		fmax=1
	}
	fp=0
	for fnum,1,fmax+1
		fname = ""+strf("%04d",fnum)+".bmp"
		title "load: "+fname
		exist fname
		if(strsize == -1){
			dialog fname+" is not found"
			_break
		}
		pos 0,0
		picload fname,1
		wait 3
		for y,0,16
			bitmask = 0x80
			a=0
			for x,0,32
				pget x,y
				if( ginfo(16) > 0 ){
					a |= bitmask
				}
				bitmask >>=1
				if(bitmask==0){
					poke fbuf,fp,(a & 0xff)
					fp++	
					bitmask = 0x80
					a = 0
				}
			next
		next
	next
	bsave "test.ani",fbuf,fp
 	dialog "変換完了test.aniで保存"
	return

▲aniファイルをSDカードに入れて、edu1ani.binを実行。
ファイル選択でaniファイルを指定するとアニメが始まります。
アニメは循環しますので、最後を表示し終えると1枚目に戻ります。
ビデオ出力もやってますので、テレビに映すこともできます。